**Tutorial IV**

**Función SI Anidada**

**Para recordar:** La función SI permite realizar una comparación lógica entre un valor y el resultado que se espera probando una condición y devolviendo un resultado si es Verdadero o Falso.

=SI(Algo es Verdadero; hacer algo; de lo contrario hacer algo diferente)

Por esto, una instrucción SI puede tener dos resultados. El primer resultado es si la comparación es Verdadera y el segundo si la comparación es Falsa.

Las instrucciones SI son extremadamente sólidas y forman la base de muchos modelos de hoja de cálculo, pero también son la causa principal de muchos de los problemas en las hojas de cálculo. Lo ideal es que una instrucción SI se aplique a condiciones mínimas, como Hombre/Mujer, Sí/No/Quizás, por nombrar algunos ejemplos, pero a veces es posible que deba evaluar escenarios más complejos que requieren el Anidamiento\* de más de 3 funciones SI juntas.

\*Anidamiento hace referencia a la práctica de unir varias funciones en una fórmula.

La función SI anidada en Excel permite evaluar múltiples condiciones y devolver diferentes resultados según el cumplimiento de estas. Esta técnica es útil cuando se tienen más de dos categorías o condiciones a evaluar.

La función SI anidada utiliza los siguientes argumentos, (en inglés la función es IF):

=SI(prueba\_lógica1; valor\_si\_verdadero1; SI(prueba\_lógica2; valor\_si\_verdadero2; SI(prueba\_lógica3; valor\_si\_verdadero3; valor\_si\_falso)))

=IF(logical\_test1, value\_if\_true1, IF(logical\_test2, value\_if\_true2, IF(logical\_test3, value\_if\_true3, value\_if\_false)))

Donde:

**prueba lógica / logical\_test:** Condición a evaluar.

**valor\_si\_verdadero / value\_if\_true:** Valor que se devuelve si la condición es verdadera.

**valor\_si\_falso / value\_if\_false:** Valor que se devuelve si ninguna de las condiciones anteriores es verdadera.

Desglose de la Sintaxis:

**prueba\_lógica1:** Primera condición que se evalúa.

**valor\_si\_verdadero1:** Valor que se devuelve si la primera condición es verdadera.

**prueba\_lógica2:** Segunda condición que se evalúa si la primera es falsa (es decir está condicionada, como en un árbol de decisiones).

**valor\_si\_verdadero2:** Valor que se devuelve si la segunda condición es verdadera.


**prueba\_lógica3:** Tercera condición que se evalúa si las dos anteriores son falsas.

**valor\_si\_verdadero3:** Valor que se devuelve si la tercera condición es verdadera.

**valor\_si\_falso:** Valor que se devuelve si ninguna de las condiciones anteriores es verdadera.

**Ejemplo:**

Consideremos una instrucción SI anidada relativamente estándar para convertir resultados de exámenes en su equivalente de la calificación mediante letras (Puntuación de 0 a 100, y equivalente a letras -como en el sistema estadounidense- de la “A” a la “F”).



=SI(D2>89;"A";SI(D2>79;"B";SI(D2>69;"C";SI(D2>59;"D";"F"))))

Esta instrucción SI anidada compleja sigue una lógica sencilla:

1. Si el resultado (en la celda D2) es mayor que 89, la calificación es A
2. Si el resultado es mayor que 79, la calificación es B
3. Si el resultado es mayor que 69, la calificación es C
4. Si el resultado es mayor que 59, la calificación es D
5. En caso contrario, la calificación es F

Cabe destacar que como el estudio y consideración de los intervalos es desde el umbral superior (89) hacia abajo, solo cuando la primera condición no se cumpla, se avanza a la revisión del siguiente umbral (79). A esto se le llama “Revisión exhaustiva de los umbrales de los intervalos”

Este ejemplo concreto es relativamente seguro porque no es probable que la correlación entre los resultados de los exámenes y las calificaciones por letras cambie, por lo que no requerirá mucho mantenimiento. Pero ¿qué sucede si necesita segmentar las calificaciones entre A+, A y A- (y así sucesivamente)? En ese caso, es necesario reescribir la instrucción SI (que tenía cuatro condiciones o funciones SI dadas las 5 letras presentes -A,B,C,D y F- ) para que pase a tener 12 condiciones (cada condición anterior, se abrió a tres opciones). Este es el aspecto que tendría la fórmula ahora:

=SI(D2>97;"A+";SI(D2>93;"A";SI(D2>89;"A-";SI(D2>87;"B+";SI(D2>83;"B";SI(D2>79;"B-"; SI(D2>77;"C+";SI(D2>73;"C";SI(D2>69;"C-";SI(D2>57;"D+";SI(D2>53;"D";SI(D2>49;"D-";"F"))))))))))))

Sigue siendo funcionalmente preciso y funcionará según lo esperado, pero tardaremos mucho tiempo en escribir y más tiempo en probar para asegurarnos de que esta función SI anidada hace lo que se desea. Otro problema evidente es que hemos tenido que escribir a mano las puntuaciones y las calificaciones por letras equivalentes. ¿Cuáles son las probabilidades de que tengamos accidentalmente un error ortográfico o de sintaxis? Imagine ahora que intenta hacer esto 64 veces con condiciones más complejas. Claro, es posible, pero ¿realmente quiere someterse a este tipo de esfuerzo y probables errores que serán muy difíciles de detectar?

Ante esto, EXCEL como siempre tiene una solución, la función SI.CONJUNTO(), que aplicada a los casos anteriores, quedaría de la siguiente manera.

**SI.CONJUNTO para 4 condiciones**

=SI.CONJUNTO(D2>89;"A";D2>79;"B";D2>69;"C";D2>59;"D";D2<=59;"F")

**SI.CONJUNTO para 12 condiciones**

=SI.CONJUNTO(D2>97;"A+";D2>93;"A";D2>89;"A-";D2>87;"B+";D2>83;"B";D2>79;"B-";D2>77;"C+";D2>73;"C";D2>69;"C-";D2>57;"D+";D2>53;"D";D2>49;"D-";D2<=49;"F")

Para profundizar sobre las funciones SI recomendamos hacer click en el siguiente enlace: <https://exceltotal.com/funcion-si-anidada/>